finish
/clear
!---------------前处理--------------
/prep7 !进入前处理器
!
!定义单元类型
!
et,1,visco106
et,2,targe169
et,3,conta171
keyopt,1,3,1
!
!定义材料特性
!
mp,ex,1,1.84e4
mp,prxy,1,0.4
tb,miso,1,0,7
!
!
tbpt,,0.005,92 !第1点
tbpt,,0.02,140 !第2点
tbpt,,0.06,194 !第3点
tbpt,,0.19,274 !第4点
tbpt,,0.5,366 !第5点
tbpt,,1,451 !第6点
tbpt,,2,556 !第7点
tbplot !显示由上述几点定义的应力应变关系曲线
!
mp,mu,2,0.15
!
!建立几何模型
!
blc4,0,0,1800,180
!
k,,1200,-800
k,,1200,0
k,,2000,0
k,,0,180
k,,1000,1180
k,,1000,1580
l,7,6
l,6,5
l,9,10
lfillt,5,6,400
local,11,1,0,1180,0
csys,11
l,8,9
csys,0
csdele,11,
lsel,s,line,,2
lsel,a,line,,4,7,1
lesize,all,,,4
lsel,s,line,,1
lsel,a,line,,3
lesize,all,,,30
lsel,s,line,,8
lsel,a,line,,9
lesize,all,,,8,,,,,1
allsel
aatt,1,,1
amesh,all
!r,1,,,
r,2,,,2,,,,
lsel,s,line,,5,9,1
latt,2,2,2
lsel,s,line,,1,3,2
latt,2,2,3
lsel,a,line,,5,9,1
lmesh,all
finish !有限元网格模型生成完毕
!
!---------------加载与求解--------------
/solu !进入求解器
!施加载荷与约束
!
nsel,s,loc,x,0
d,all,,,,,,ux
allsel
lsel,s,line,,5,6
lsel,a,line,,8
nsll,s
d,all,all
lsel,s,line,,7,9,2
nsll,s,1
d,all,uy,-1500
!
allsel
antype,0
nlgeom,1
autots,1
deltim,0.5,0.05,1
time,25
cnvtol,f,,0.1,2
outres,all,5
lnsrch,1
neqit,35
pred,on,,on
ncnv,,,,,
solve
finish !求解完毕
!
!---------------后处理--------------
/post1
plnsol,u,sum,2,1
plnsol,s,eqv,2,1
plnsol,eppl,eqv,2,1
ancntr,20,0.5,0