/prep7
et,1,solid236 !!定义空气
et,2,solid236,1 !!定义支架、外壳
et,3,solid236 !!定义导线
et,4,solid236 !!定义绝缘
M=1500
!!定义材料属性
mp,murx,1,1 !!空气材料属性
mp,murx,2,M !!支架、外壳材料属性
mp,rsvx,2,3.00e-8
mp,murx,3,1 !!导线材料属性
mp,murx,4,5 !!绝缘材料属性
!!赋予材料属性
vsel,s,volu,,3,12 !!支架
vsel,a,volu,,1 !!外壳
cm,iron,volu
vsel,s,volu,,2 !!水泥
cm,air,volu
vsel,s,volu,,14 !!导线
vsel,a,volu,,16
vsel,a,volu,,18
vsel,a,volu,,20
vsel,a,volu,,22
vsel,a,volu,,24
cm,line,volu
vsel,s,volu,,13 !!绝缘
vsel,a,volu,,15
vsel,a,volu,,17
vsel,a,volu,,19
vsel,a,volu,,21
vsel,a,volu,,23
cm,jueyuan,volu
cmsel,s,air
vatt,1,,1
cmsel,s,iron
vatt,2,,2
cmsel,s,line
vatt,3,,3
cmsel,s,jueyuan
vatt,4,,4
!!划分网格
allsel,all
cmsel,s,air
esize,10/1000
mshape,1,3d
mshkey,0
vmesh,all
allsel,all
cmsel,s,iron
esize,10/1000
mshape,1,3d
mshkey,0
vmesh,all
allsel,all
cmsel,s,line
esize,10/1000
vsweep,all
allsel,all
allsel,all
cmsel,s,jueyuan
esize,10/1000
vsweep,all
allsel,all
!!边界条件
allsel,all
asel,s,,,2
asel,a,,,5
nsla,s,1
d,all,az,0
!!加载荷
!!A相两路导线
allsel,all
asel,s,area,,319
nsla,s,1
cp,1,volt,all
f,ndnext(0),amps,1170
!*get,Nmin,node,,num,min
!d,Nmin,amps,1170
asel,s,area,,320
nsla,s,1
d,all,volt,0
nsel,all
asel,s,area,,279
nsla,s,1
cp,2,volt,all
f,ndnext(0),amps,1170
asel,s,area,,280
nsla,s,1
d,all,volt,0
nsel,all
!!B相两路导线
asel,s,area,,289
nsla,s,1
cp,3,volt,all
f,ndnext(0),amps,-585,-1013
asel,s,area,,290
nsla,s,1
d,all,volt,0
nsel,all
asel,s,area,,299
nsla,s,1
cp,4,volt,all
f,ndnext(0),amps,-585,-1013
asel,s,area,,300
nsla,s,1
d,all,volt,0
nsel,all
!!C相两路导线
asel,s,area,,309
nsla,s,1
cp,5,volt,all
f,ndnext(0),amps,-585,1013
asel,s,area,,310
nsla,s,1
d,all,volt,0
nsel,all
asel,s,area,,329
nsla,s,1
cp,6,volt,all
f,ndnext(0),amps,-585,1013
asel,s,area,,330
nsla,s,1
d,all,volt,0
nsel,all
/solu
antyp,harm
harfrq,50
solve
finish
/post1
set,first
esel,s,mat,,2
PLVECT,JT, , , ,VECT,ELEM,ON,0 !涡流
PLVECT,B, , , ,VECT,ELEM,ON,0 !磁场B
PLVECT,H, , , ,VECT,ELEM,ON,0 !磁场H
PLVECT,EF, , , ,VECT,ELEM,ON,0 !电场强度
PLNSOL, JC,SUM, 0 !涡流云图
PLESOL, JHEAT,, 0 !焦耳热功率,即涡流损耗
/post1 !算涡流损耗数值,查看时,点Parameters->Scalar Parameters->heatsum即总涡流损耗
allsel,all
*get,AllElemNum,elem,0,count
set,first
heatsum=0
heatsum1=0
esel,s,mat,,2
*do,i,1,AllElemNum
*if,esel(i),eq,1,then
*get,jheat,elem,i,jheat
*get,jvolu,elem,i,volu
heatsum=heatsum+jheat*jvolu
heatsum1=heatsum1+jheat
*endif
*enddo