finish
/clear
/filename,Box-Girder-bridge,1
/title,Box-Girder-bridge
/prep7
*dim,Area,array,5
Area(1)=6.695091
Area(2)=4.032462
Area(3)=3.070164
Area(4)=5.249138
Area(5)=6.458040
*dim,Iz,array,5
Iz(1)=0.90321092
Iz(2)=1.13405451
Iz(3)=0.91741062
Iz(4)=1.25899033
Iz(5)=1.28362845
*dim,Iy,array,5
Iy(1)=17.64922286
Iy(2)=11.55677411
Iy(3)=10.31877450
Iy(4)=12.48708119
Iy(5)=13.09906791
et,1,beam3
r,1,Area(1),Iz(1),1.25!!A截面实常数
r,2,Area(2),Iz(2),1.45!!B截面实常数
r,3,Area(3),Iz(2),1.45!!C截面实常数
r,4,Area(4),Iz(4),1.45!!D截面实常数
r,5,Area(5),Iz(5),1.45!!E截面实常数
alpha1=1 !!边跨损伤折减系数
alpha2=1 !!中跨损伤折减系数
mp,ex,1,alpha1*3.5e10
mp,prxy,1,0.3
mp,dens,1,2600
mp,ex,2,alpha2*3.5e10
mp,prxy,2,0.3
mp,dens,2,2600
!!!!!主梁节点绘制(半桥)
*do,i,1,361
n,i,-36.1+0.1*i
*enddo
!!!!!主梁单元分段绘制(半桥)
mat,1
type,1
real,1
*do,i,1,5
e,i,i+1
*enddo
mat,1
type,1
real,5
*do,i,1,7
e,5+i,6+i
*enddo
mat,1
*do,i,1,5
r,10+i,Area(5)*(5-i)/5+Area(2)*i/5,Iz(5)*(5-i)/5+Iz(2)*i/5,1.45
real,10+i
e,12+i,13+i
*enddo
*do,i,1,30
r,20+i,Area(2)*(30-i)/30+Area(3)*i/30,Iz(2)*(30-i)/30+Iz(3)*i/30,1.45
real,20+i
e,17+i,18+i
*enddo
real,3
*do,i,1,99
e,47+i,48+i
*enddo
*do,i,1,40
r,100+i,Area(3)*(40-i)/40+Area(2)*i/40,Iz(3)*(40-i)/40+Iz(2)*i/40,1.45
real,100+i
e,146+i,147+i
*enddo
*do,i,1,5
r,200+i,Area(2)*(5-i)/5+Area(4)*i/5,Iz(2)*(5-i)/40+Iz(4)*i/5,1.45
real,200+i
e,186+i,187+i
*enddo
*do,i,1,9
r,300+i,Area(4)*(9-i)/9+Area(5)*i/9,Iz(4)*(9-i)/9+Iz(5)*i/9,1.45
real,300+i
e,191+i,192+i
*enddo
!!!!!!!!!!边跨完毕
!!!!!!!!!!中跨箱梁
*do,i,1,9
r,400+i,Area(5)*(9-i)/9+Area(4)*i/9,Iz(5)*(9-i)/9+Iz(4)*i/9,1.45
mat,2
real,400+i
e,200+i,201+i
*enddo
*do,i,1,5
r,500+i,Area(4)*(5-i)/5+Area(2)*i/5,Iz(4)*(5-i)/40+Iz(2)*i/5,1.45
mat,2
real,500+i
e,209+i,210+i
*enddo
*do,i,1,40
r,600+i,Area(2)*(40-i)/40+Area(3)*i/40,Iz(3)*(40-i)/40+Iz(3)*i/40,1.45
mat,2
real,600+i
e,214+i,215+i
*enddo
*do,i,1,106
mat,2
real,3
e,254+i,255+i
*enddo
!***************镜像****************
esel,all
nsym,x,1000,all
esym,,1000,all
allsel
nummrg,all
allsel
/replot
allsel
d,6,uy
d,201,uy
d,201,ux
d,1201,uy
d,1201,ux
d,1006,uy
!*************影响线绘制*********************************************************
nsel,all$n0=1 !选择所有节点为作用节点群,起始节点号为1
nmax=ndinqr(0,13) !获取作用节点群总数,即单位力作用点数
*dim,p1node,array,nmax !定义作用节点群数组,存放单位力作用的节点号
*dim,nodex,array,nmax !定义节点群X坐标数组,存放与节点号对应的X坐标
p1node(1)=n0 !将起始节点号赋予作用节点群数组P1node(1)
nodex(1)=nx(n0) !将n0节点的X坐标赋予数组nodex(1)
*do,i,2,nmax !循环,从2~NMAX(节点群总数)
ni=nnear(n0) !获取距离n0节点最近的节点号,并赋予ni
p1node(i)=ni !将ni存入数组p1node(i),注意下标为节点群序号
nodex(i)=nx(ni) !将ni节点的X坐标存入数组nodex(i)
nsel,u,,,n0 !从当前节点集体中去掉n0节点,以单向获取节点号
n0=ni
*enddo !将ni节点号赋予变量n0,实现循环中节点号的变化
!加载求解,这里定义荷载步并连续求解
/solu
allsel,all !选择所有图素,防止出现模型不完整
*do,i,1,nmax !以作用节点群总数循环
time,i
fdele,all,all
f,p1node(i),fy,-1
solve
*enddo
/post26
nsol,3,72,u,y !先任意定义一个变量,以便执行Vput命令
vput,nodex,2 !将数组nodex()赋予变量2,即变量2为X坐标
nsol,3,101,u,y !定义节点101的UY为变量3
nsol,4,361,u,y!定义节点361的UY为变量3
esol,5,201,201,m,z!定义单元200节点201端的MZ为变量5
esol,6,98,98,m,z
esol,7,360,361,m,z
*dim,YXX,array,721,6
vget,YXX(1,1),2
vget,YXX(1,2),3
vget,YXX(1,3),4
vget,YXX(1,4),5
vget,YXX(1,5),6
vget,YXX(1,6),7
*create,temp
*cfopen,'output','txt'
*vwrite,YXX(1,1),YXX(1,2),YXX(1,3),YXX(1,4),YXX(1,5),YXX(1,6)
(3d15.6,' ',3d15.6,' ',3d15.6,' ',3d15.6,' ',3d15.6,' '3d15.6,' ')
*cfclos
*end
/input,temp
!*************静力求解**************
/solu
antype,0
fdele,all,all
allsel
acel,,9.8*1.2,
esel,s,elem,,6,200,1
esel,a,elem,,366,560,1
sfbeam,all,2,pres,21000*1.4
allsel
f,100,fy,-120000*1.4
solve
fini
/post1
ETABLE,MI,SMISC,6 !单元I点弯矩
ETABLE,MJ,SMISC,12 !单元J点弯矩
plls,MI,MJ
fini
!*************模态分析****************
/solu
antype,modal
modopt,lanb,10
mxpand,10
acel,0,9.8
allsel
solve
finish
评论1