.版本 2
.支持库 iext
.程序集 窗口程序集1
.子程序 __启动窗口_创建完毕
内存.提升进程权限 ()
内存操作.提升权限 ()
提升进程权限D ()
' 本源码转载 易酷论坛 http://bbs.e7bai.com 每天给你N多的稳定源码 放出N多易语言教程 制作外挂教程等等
时钟1.时钟周期 ＝ 1000
时钟2.时钟周期 ＝ 1000
.子程序 __启动窗口_将被销毁
CloseHandle (操作句柄)
.子程序 _按钮1_被单击
载入 (进程窗口, _启动窗口, 假)
' 本源码转载 易酷论坛 http://bbs.e7bai.com 每天给你N多的稳定源码 放出N多易语言教程 制作外挂教程等等
.子程序 _组合框2_列表项被选择
.如果真 (组合框2.取项目文本 (组合框2.现行选中项) ＝ “文本型” 且 组合框1.取项目数 () ≠ 1)
组合框1.清空 ()
组合框1.加入项目 (“文本搜索”, )
组合框1.现行选中项 ＝ 0
标签2.标题 ＝ “输入文本：”
选择框1.可视 ＝ 假
返回 ()
.如果真结束
.如果真 (组合框2.取项目文本 (组合框2.现行选中项) ＝ “4字节”)
.如果真 (组合框1.取项目数 () ≠ 2)
组合框1.清空 ()
组合框1.加入项目 (“精确搜索”, )
组合框1.加入项目 (“模糊搜索”, )
组合框1.现行选中项 ＝ 0
标签2.标题 ＝ “输入数值：”
选择框1.可视 ＝ 真
.如果真结束
返回 ()
.如果真结束
.如果真 (组合框2.取项目文本 (组合框2.现行选中项) ＝ “浮点数” 或 组合框2.取项目文本 (组合框2.现行选中项) ＝ “双精度小数” 或 组合框2.取项目文本 (组合框2.现行选中项) ＝ “单字节” 或 组合框2.取项目文本 (组合框2.现行选中项) ＝ “双字节” 或 组合框2.取项目文本 (组合框2.现行选中项) ＝ “8字节”)
信息框 (“对不起！目前只能搜索【文本型】或【4字节】的数据搜索。”, 0, )
组合框2.现行选中项 ＝ 2
.如果真 (组合框1.取项目数 () ≠ 2)
组合框1.清空 ()
组合框1.加入项目 (“精确搜索”, )
组合框1.加入项目 (“模糊搜索”, )
组合框1.现行选中项 ＝ 0
标签2.标题 ＝ “输入数值：”
选择框1.可视 ＝ 真
.如果真结束
返回 ()
.如果真结束
.子程序 _按钮2_被单击, , , 开始搜索 按钮
.如果真 (操作句柄 ＝ 0)
信息框 (“请先打开一个进程！”, 0, )
返回 ()
.如果真结束
.如果 (按钮2.标题 ＝ “开始搜索”)
开始搜索 ()
.否则
按钮2.标题 ＝ “开始搜索”
按钮3.禁止 ＝ 真
组合框2.禁止 ＝ 假
超级列表框1.全部删除 ()
标签5.标题 ＝ “搜索结果：”
.如果结束
返回 ()
.子程序 开始搜索
.局部变量 搜索内容, 字节集
.局部变量 整数, 整数型
.如果真 (组合框2.取项目文本 (组合框2.现行选中项) ＝ “文本型”) ' 搜索文本内容
.如果真 (编辑框1.内容 ＝ “”)
信息框 (“搜索内容不能为空！”, 0, )
返回 ()
.如果真结束
搜索内容 ＝ 到字节集 (编辑框1.内容) ' 文本转为字节集
搜索变量 ＝ 搜索内容
搜索 (搜索内容)
按钮3.禁止 ＝ 假
按钮2.标题 ＝ “重新搜索”
组合框2.禁止 ＝ 真
返回 ()
.如果真结束
.如果真 (组合框2.取项目文本 (组合框2.现行选中项) ＝ “4字节”)
.如果真 (编辑框1.内容 ＝ “”)
信息框 (“搜索内容不能为空！”, 0, )
返回 ()
.如果真结束
.如果 (选择框1.选中 ＝ 真)
十六转十 (“0x” ＋ 编辑框1.内容, 1, 整数)
.否则
整数 ＝ 到数值 (编辑框1.内容)
.如果结束
搜索内容 ＝ 到字节集 (整数) ' 整数转为字节集
搜索变量 ＝ 搜索内容
搜索 (搜索内容)
按钮3.禁止 ＝ 假
按钮2.标题 ＝ “重新搜索”
组合框2.禁止 ＝ 真
' 信息框 (“本功能未开放！”, 0, )
返回 ()
.如果真结束
.子程序 搜索
.参数 搜索内容, 字节集
.局部变量 长度, 整数型
.局部变量 内存块长度, 整数型
.局部变量 内存地址, 整数型
.局部变量 内存块信息, MEMORY_BASIC_INFORMATION
.局部变量 数据缓冲区, 字节集
.局部变量 读取结果, 整数型
.局部变量 开始地址, 整数型
.局部变量 计次, 整数型
.局部变量 时间, 整数型
时间 ＝ 取启动时间 ()
清除数组 (搜索结果)
长度 ＝ 取字节集长度 (搜索内容)
内存块长度 ＝ 28
.判断循环首 (VirtualQueryEx (操作句柄, 内存地址, 内存块信息, 内存块长度) ≠ 0)
.如果真 (内存块信息.Type ＝ #MEM_PRIVATE 且 内存块信息.Protect ＝ #PAGE_READWRITE)
数据缓冲区 ＝ 取空白字节集 (内存块信息.RegionSize)
读取结果 ＝ ReadProcessMemory (操作句柄, 内存地址, 数据缓冲区, 内存块信息.RegionSize, 0)
.判断循环首 (读取结果 ＞ 0)
开始地址 ＝ 寻找字节集 (数据缓冲区, 搜索内容, 开始地址) ' 查找是否有要搜索的数据
.如果 (开始地址 ＝ -1)
跳出循环 ()
.否则
加入成员 (搜索结果, 到数值 (内存地址 ＋ 开始地址 － 1))
.如果结束
开始地址 ＝ 开始地址 ＋ 长度
.判断循环尾 ()
.如果真结束
内存地址 ＝ 内存地址 ＋ 内存块信息.RegionSize
进度条1.位置 ＝ 内存地址 ÷ 2147483647 × 100
处理事件 ()
.判断循环尾 ()
进度条1.位置 ＝ 0
超级列表框1.全部删除 ()
.如果真 (取数组成员数 (搜索结果) ＜ 300)
.如果 (列表框1地址状态 ＝ 真) ' 10进制为真 16进制为假
.计次循环首 (取数组成员数 (搜索结果), 计次)
超级列表框1.插入表项 (, 到文本 (搜索结果 [计次]), , , , 搜索结果 [计次])
.计次循环尾 ()
.否则
.计次循环首 (取数组成员数 (搜索结果), 计次)
超级列表框1.插入表项 (, 取十六进制文本 (搜索结果 [计次]), , , , 搜索结果 [计次])
.计次循环尾 ()
.如果结束
.如果真结束
标签5.标题 ＝ “搜索结果：” ＋ 到文本 (取数组成员数 (搜索结果))
标签6.标题 ＝ “运行时间：” ＋ 到文本 (取启动时间 () － 时间) ＋ “毫秒”
返回 () ' 本源码转载 易酷论坛 http://bbs.e7bai.com 每天给你N多的稳定源码 放出N多易语言教程 制作外挂教程等等
.子程序 _按钮5_被单击
超级列表框1.全部删除 ()
.子程序 _时钟1_周期事件
.局部变量 计次, 整数型
.局部变量 临时, 字节集
.局部变量 整数, 整数型
.如果真 (组合框2.取项目文本 (组合框2.现行选中项) ＝ “文本型”)
计次 ＝ 0
.计次循环首 (超级列表框1.取表项数 (), 计次)
临时 ＝ 取空白字节集 (取字节集长度 (到字节集 (搜索变量)))
ReadProcessMemory (操作句柄, 超级列表框1.取表项数值 (计次 － 1), 临时, 取字节集长度 (到字节集 (搜索变量)), 0)
.如果真 (超级列表框1.取标题 (计次 － 1, 1) ≠ 到文本 (临时))
超级列表框1.置标题 (计次 － 1, 1, 到文本 (临时))
.如果真结束
.计次循环尾 ()
返回 ()
.如果真结束
.如果真 (组合框2.取项目文本 (组合框2.现行选中项) ＝ “4字节”)
计次 ＝ 0
.计次循环首 (超级列表框1.取表项数 (), 计次)
读内存整数 (操作句柄, 超级列表框1.取表项数值 (计次 － 1), 整数, 4, 0)
.如果真 (超级列表框1.取标题 (计次 － 1, 1) ≠ 到文本 (整数))
超级列表框1.置标题 (计次 － 1, 1, 到文本 (整数))
.如果真结束
.计次循环尾 ()
返回 ()
.如果真结束
.子程序 _按钮3_被单击, , , 二次搜索按钮
.局部变量 搜索内容, 字节集
.局部变量 整数, 整数型
.如果真 (组合框2.取项目文本 (组合框2.现行选中项) ＝ “文本型”) ' 搜索文本内容
.如果真 (编辑框1.内容 ＝ “”)
信息框 (“搜索内容不能为空！”, 0, )
返回 ()
.如果真结束
搜索内容 ＝ 到字节集 (编辑框1.内容) ' 文本转为字节集
搜索变量 ＝ 搜索内容
二次搜索 (搜索内容)
' 按钮3.禁止 ＝ 假
' 按钮2.标题 ＝ “重新搜索”
' 组合框2.禁止 ＝ 真
返回 ()
.如果真结束
.如果真 (组合框2.取项目文本 (组合框2.现行选中项) ＝ “4字节”)
.如果真 (编辑框1.内容 ＝ “”)
信息框 (“搜索内容不能为空！”, 0, )
返回 ()
.如果真结束
.如果 (选择框1.选中 ＝ 真)
十六转十 (“0x” ＋ 编辑框1.内容, 1, 整数)
.否则
整数 ＝ 到数值 (编辑框1.内容)
.如果结束
搜索内容 ＝ 到字节集 (整数) ' 整数转为字节集
输出调试文本 (到文本 (取字节集长度 (搜索内容)))
搜索变量 ＝ 搜索内容
二次搜索 (搜索内容)
' 按钮3.禁止 ＝ 假
' 按钮2.标题 ＝ “重新搜索”
' 组合框2.禁止 ＝ 真
' 信息框 (“本功能未开放！”, 0, )
返回 ()
.如果真结束
.子程序 二次搜索
.参数 搜索内容, 字节集
.局部变量 计次, 整数型
.局部变量 临时字节集, 字节集
清除数组 (二次搜索结果)
.计次循环首 (取数组成员数 (搜索结果), 计次)
临时字节集 ＝ 取空白字节集 (取字节集长度 (搜索内容))
ReadProcessMemory (操作句柄, 搜索结果 [计次], 临时字节集, 取字节集长度 (搜索内容), 0)
.如果真 (临时字节集 ＝ 搜索内容)
加入成员 (二次搜索结果, 搜索结果 [计次])
.如果真结束
进度条1.位置 ＝ 计次 ÷ 取数组成员数 (搜索结果) × 100
' 处理事件 ()
.计次循环尾 ()
进度条1.位置 ＝ 0
计次 ＝ 0
超级列表框1.全部删除 ()
.如果真 (取数组成员数 (二次搜索结果) ＜ 300)
.如果 (列表框1地址状态 ＝ 真) ' 10进制为真 16进制为假
.计次循环首 (取数组成员数 (二次搜索结果), 计次)
超级列表框1.插入表项 (, 到文本 (二次搜索结果 [计次]), , , , 二次搜索结果 [计次])
.计次循环尾 ()
.否则
.计次循环首 (取数组成员数 (二次搜索结果), 计次)
超级列表框1.插入表项 (, 取十六进制文本 (二次搜索结果 [计次]), , , , 二次搜索结果 [计次])
.计次循环尾 ()
.如果结束
.如果真结束
搜索结果 ＝ 二次搜索结果
标签5.标题 ＝ “搜索结果：” ＋ 到文本 (取数组成员数 (二次搜索结果))
返回 ()
.子程序 _超级列表框1_表头被单击
.参数 被单击列索引, 整数型
.局部变量 计次, 整数型
.如果真 (被单击列索引 ＝ 0)' 本源码转载 易酷论坛 http://bbs.e7bai.com 每天给你N多的稳定源码 放出N多易语言教程 制作外挂教程等等
.如果真 (超级列表框1.取列标题 (0) ＝ “地址(10进制)”)
计次 ＝ 0
.计次循环首 (超级列表框1.取表项数 (), 计次)
超级列表框1.置标题 (计次 － 1, 0, 取十六进制文本 (超级列表框1.取表项数值 (计次 － 1)))
.计次循环尾 ()
超级列表框1.置列标题 (0, “地址(16进制)”)
列表框1地址状态 ＝ 假 ' 10进制为真 16进制为假
返回 ()
.如果真结束
.如果真 (超级列表框1.取列标题 (0) ＝ “地址(16进制)”)
计次 ＝ 0
.计次循环首 (超级列表框1.取表项数 (), 计次)
超级列表框1.置标题 (计次 － 1, 0, 到文本 (超级列表框1.取表项数值 (计次 － 1)))
.计次循环尾 ()
超级列表框1.置列标题 (0, “地址(10进制)”)
列表框1地址状态 ＝ 真 ' 10进制为真 16进制为假
返回 ()
.如果真结束
.如果真结束
返回 ()
.子程序 _选择框1_被单击
.局部变量 a, 长整数型
.如果 (选择框1.选中 ＝ 真)
编辑框1.内容 ＝ 取十六进制文本 (到数值 (编辑框1.内容))
.否则
十六转十 (“0x” ＋ 编辑框1.内容, 1, a)
编辑框1.内容 ＝ 到文本 (a)
.如果结束
返回 ()
.子程序 _时钟2_周期事件
.局部变量 计次, 整数型
.局部变量 整数, 整数型
.局部变量 字节集, 字节集
.如果真 (超级列表框2地址 ＝ 0)
返回 ()
.如果真结束
.计次循环首 (14, 计次)
读内存整数 (操作句柄, 超级列表框2地址 ＋ (计次 － 1) × 4, 整数, 4, 0)
字节集 ＝ 取空白字节集 (20)
ReadProcessMemory (操作句柄, 超级列表框2地址 ＋ (计次 － 1) × 4, 字节集, 20, 0)
.如果真 (超级列表框2.取标题 (计次 － 1, 2) ≠ 到文本 (整数))
超级列表框2.置标题 (计次 － 1, 2, 到文本 (整数))
.如果真结束
.如果真 (超级列表框2.取标题 (计次 － 1, 3) ≠ 到文本 (字节集))
超级列表框2.置标题 (计次 － 1, 3, 到文本 (字节集))
.如果真结束
.计次循环尾 ()
返回 ()
.子程序 _超级列表框1_表项被激活
.局部变量 计次, 整数型
超级列表框2地址 ＝ 超级列表框1.取表项数值 (超级列表框1.现行选中项)
超级列表框2.全部删除 ()
.计次循环首 (14, 计次)
超级列表框2.插入表项 (, 到文本 ((计次 － 1) × 4), , , , )
超级列表框2.置标题 (计次 － 1, 1, 到文本 (超级列表框2地址 ＋ (计次 － 1) × 4))
.计次循环尾 ()
_时钟2_周期事件 ()
返回 ()
