crc16kermit-vb6.0.txt

'CRC
Public Function ComputeCRC(ByRef inBuf() As Byte, ByVal nStart As Long, ByVal nBytes As Long) As Long
    '*****************************************************
    ' Purpose: Calculates the 16-bit CCITT CRC check of
    ' a sequence of bytes
    ' Inputs: inBuf() input array of bytes
    ' nStart starting point in inBuf
    ' nBytes number of bytes to use
    ' Returns: The unsigned 16-bit CRC as a long
    ' Method: Devised by Andy Lowry, Columbia University
    ' The magic number &H1081 is derived from
    ' the CRC-CCITT polynomial x^16+x^12+x^5+1
    '*****************************************************
     Dim crc As Long 'running CRC value
     Dim Q As Long 'intermediate value
     Dim c As Long 'byte being used, as a long
     Dim i As Long 'loop counter
     
     crc = 0
     For i = nStart To nStart + nBytes - 1
     c = inBuf(i)
     Q = (crc Xor c) And &HF& 'low nibble
     crc = (crc \ &H10&) Xor (Q * &H1081&)
     Q = (crc Xor (c \ &H10&)) And &HF& 'high nibble
     crc = (crc \ &H10&) Xor (Q * &H1081&)
     Next i
     ComputeCRC = crc
End Function

'6位卡金额变为CRC字符串